Пример ограничения числа одновременно открытых позиций

//+------------------------------------------------------------------+
//|                                           limit_trades.mq4 |
//|                Copyright (c) 2007, Andrey Vedikhin |
//|                                http://www.vedikhin.ru |
//+------------------------------------------------------------------+
#property copyright "Copyright (c) 2007, Andrey Vedikhin"
#property link      "http://www.vedikhin.blog-forex.org"

//+------------------------------------------------------------------+
//| expert initialization function                         |
//+------------------------------------------------------------------+
int init()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert deinitialization function                      |
//+------------------------------------------------------------------+
int deinit()
  {
//----
   
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| expert start function                                   |
//+------------------------------------------------------------------+
int start()
  {
//----
    int MaxNumberOfTrades = 3;
    
    if (!StartTrading(MaxNumberOfTrades)) return(0);
    OrderSend(Symbol(), OP_BUY, 0.1, Ask, 3, 0, 0);
    StopTrading();    
//----
   return(0);
  }
//+-------------------------------------------------------------------+
//| StartTrading()                                               |
//| Функция должна быть вызвана до OrderSend()|
//|                                                                   |
//| Возвращает:                                                 |
//|   true - если можно открывать новую позицию|
//|   false - если лимит исчерпаг или ошибка       |
//+-------------------------------------------------------------------+
bool StartTrading(int max_trades)
  {
    // залокируем критическую секцию
    if (Lock("MaxTrades")!=0) return(false);
 
    int open_trades = OrdersTotal();
    
    if (open_trades<max_trades)
      return(true);
    else
      {
       Print("Уже открыто ", open_trades, " позиций");
       Unlock("MaxTrades");
       return(false);
      }
  }
//+------------------------------------------------------------------------+
//| StopTrading()                                                    |
//| Функция должна быть вызвана после OrderSend()|
//+------------------------------------------------------------------------+
void StopTrading()
  {
    Unlock("MaxTrades");
    return;
  }
//+------------------------------------------------------------------+
//| Lock()                                                        |
//|                                                                  |
//| Возвращает:                                                |
//|   0 - если "критическая секция" успешно        |
//|        заблокирована                                     |
//|   1 - в случае ошибки                                   |
//|   2 - эксперт остановлен                              |
//|   3 - по таймауту (слишком долго ждали)       |
//+------------------------------------------------------------------+
int Lock(string GlobVarName, int timeout = 0)
  {
    string critical_section = GlobVarName+"Lock";
  
    // проверим, существует ли переменная critical_section
    if (!GlobalVariableCheck(critical_section))
      {
       if (GetLastError()!=0) return(1);
       
       // переменная не существует, создадим ее
       if (GlobalVariableSet(critical_section, -1.0)==0) return(1);
       // переменная создана
      }
    
    int StartTime = GetTickCount();
    
    // ждем "зеленового света"
    while (true)
      {
        // проверить, не загорелся ли "зеленый свет"
        if (GlobalVariableGet(critical_section)==-1.0)
          {
           // "зеленый свет" загорелся, зажигаем "красный свет"
           if (GlobalVariableSetOnCondition(critical_section, 1.0, -1.0)) return(0);
           
           // нас опередили, поэтому ждем "зеленового света"
          }
        
        // проверим, не остановлен ли эксперт
        if (IsStopped()) return(2);


        // таймаут не истек?
        if (timeout!=0)
          {
            if ((GetTickCount()-StartTime)>timeout*1000) return(3);
          }
          
        // спим 0.1 секунды
        Sleep(100);
      }
  }

//+------------------------------------------------------------------+
//| Unlock()                                                     |
//|                                                                  |
//| Возвращает:                                                |
//|   0 - если "критическая секция" успешно        |
//|        разблокирована                                    |
//|   1 - в случае ошибки                                   |
//|   2 - эксперт остановлен                               |
//|   3 - по таймауту (слишком долго ждали)       |
//+------------------------------------------------------------------+
int Unlock(string GlobVarName, int timeout = 0)
  {
    string critical_section = GlobVarName+"Lock";
  
    // проверим, существует ли переменная critical_section
    if (!GlobalVariableCheck(critical_section))
      {
       if (GetLastError()!=0) return(1);
       
       // переменная не существует, создадим ее
       if (GlobalVariableSet(critical_section, -1.0)==0) return(1);
       
       // переменная создана, поэтому выходим
       return(-1.0);
      }
      
    int StartTime = GetTickCount();
    
    // бесконечный цикл
    while (true)
      {
        // пытаемся установить "зеленый свет"
        if (GlobalVariableSetOnCondition(critical_section, -1.0, 1.0)) return(0);


        // проверим, не остановлен ли эксперт
        if (IsStopped()) return(2);

        // таймаут не истек?
        if (timeout!=0)
          {
            if ((GetTickCount()-StartTime)>timeout*1000) return(3);
          }
          
        // спим 0.1 секунды
        Sleep(100);
      }
  }

В следующем выпуске я расскажу о ночной торговле.

Все статьи по теме "Пишем советников для MetaTrader 4".

• Механическая торговая система - миф или реальность?
• С чего начать при написании советника:
  

  	-	Создаем нового советника
  	-	Настраиваем параметры.

• Язык MetaQuotes Language 4:
  

  	-	Структура советника.
  	-	Создаем собственные функции. Функции init(), start() и deinit().
  	-	Исходный код нашего первого советника.
  	-	Использование констант в эксперте.
  	-	Хранение данных в переменных: локальные, статические, внешние и глобальные переменные. Параметры функций.
  	-	Операторы: Составной оператор. Оператор присваивания (арифметические операции, операции отношения, логические операции НЕ, ИЛИ и И, побитовые операции). Условный оператор. Цикл while. Цикл for. Break. Сontinue. Переключатель Switch.
  	-	Получение информации об ордере: OrderSelect(). OrdersTotal(). HistoryTotal(). OrderClosePrice(). OrderStopLoss(). OrderType(). OrderCloseTime(). OrderTakeProfit(). OrderSymbol(). OrderComment(). OrderSwap(). OrderCommission(). OrderOpenPrice(). OrderTicket(). OrderProfit(). OrderOpenTime(). OrderExpiration(). OrderMagicNumber().
  	-	Управление ордерами и открытие/закрытие позиций: OrderSend(). OrderModify(). OrderDelete(). OrderClose(). OrderClosyBy().
  	-	Ошибки: GetLastError(). Коды ошибок.
  	-	Секреты правильной торговли: IsExpertEnabled(). IsTradeContextBusy(). IsTradeAllowed(). Как бороться с ошибкой ERR_TRADE_CONTEXT_BUSY (146). IsStopped(). RefreshRates(). Выдерживаем паузу между сделками. IsTesting().
  	-	Глобальные переменные: GlobalVariableCheck(). GlobalVariableSet(). GlobalVariableSetOnCondition(). Как дождаться освобождения торгового потока. GlobalVariableGet(). GlobalVariableDel(). "Критическая секция": разграничение доступа к ресурсу. GlobalVariablesTotal(). GlobalVariableName(). GlobalVariablesDeleteAll().
  	-	Глобальные массивы: Count(). AddItem(). SearchItem(). GetItem(). DeleteItem(). Сортировка методом пузырька. Sort().
  	-	Полезные примеры: Как ограничить количество одновременно открытых позиций/отложенных ордеров. Торговля в ночное время.